两天终于成了

baiyksygg

baiyksygg

//
//   FILE:  dht11_test1.pde
// PURPOSE: DHT11 library test sketch for Arduino
//

//Celsius to Fahrenheit conversion
double Fahrenheit(double celsius)
{
  return 1.8 * celsius + 32;
}

// fast integer version with rounding
//int Celcius2Fahrenheit(int celcius)
//{
//  return (celsius * 18 + 5)/10 + 32;
//}


//Celsius to Kelvin conversion
double Kelvin(double celsius)
{
  return celsius + 273.15;
}

// dewPoint function NOAA
// reference (1) : http://wahiduddin.net/calc/density_algorithms.htm
// reference (2) : http://www.colorado.edu/geography/weather_station/Geog_site/about.htm
//
double dewPoint(double celsius, double humidity)
{
  // (1) Saturation Vapor Pressure = ESGG(T)
  double RATIO = 373.15 / (273.15 + celsius);
  double RHS = -7.90298 * (RATIO - 1);
  RHS += 5.02808 * log10(RATIO);
  RHS += -1.3816e-7 * (pow(10, (11.344 * (1 - 1 / RATIO ))) - 1) ;
  RHS += 8.1328e-3 * (pow(10, (-3.49149 * (RATIO - 1))) - 1) ;
  RHS += log10(1013.246);

  // factor -3 is to adjust units - Vapor Pressure SVP * humidity
  double VP = pow(10, RHS - 3) * humidity;

  // (2) DEWPOINT = F(Vapor Pressure)
  double T = log(VP / 0.61078); // temp var
  return (241.88 * T) / (17.558 - T);
}

// delta max = 0.6544 wrt dewPoint()
// 6.9 x faster than dewPoint()
// reference: http://en.wikipedia.org/wiki/Dew_point
double dewPointFast(double celsius, double humidity)
{
  double a = 17.271;
  double b = 237.7;
  double temp = (a * celsius) / (b + celsius) + log(humidity * 0.01);
  double Td = (b * temp) / (a - temp);
  return Td;
}


#include <dht11.h>
#include <LiquidCrystal.h>
dht11 DHT11;
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
#define DHT11PIN 10

void setup()
{
  Serial.begin(115200);
  Serial.println("DHT11 TEST PROGRAM ");
  Serial.print("LIBRARY VERSION: ");
  Serial.println(DHT11LIB_VERSION);
  Serial.println();
  lcd.begin(16, 2);
  lcd.print("hello,world!");
}

void loop()
{
  Serial.println("\n");

  int chk = DHT11.read(DHT11PIN);

  Serial.print("Read sensor: ");
  switch (chk)
  {
    case DHTLIB_OK:
      Serial.println("OK");
      break;
    case DHTLIB_ERROR_CHECKSUM:
      Serial.println("Checksum error");
      break;
    case DHTLIB_ERROR_TIMEOUT:
      Serial.println("Time out error");
      break;
    default:
      Serial.println("Unknown error");
      break;
  }
  Serial.print("Humidity (%): ");
  Serial.println((float)DHT11.humidity, 2);
  lcd.setCursor(0, 0);
  lcd.print("Humi %:");
  lcd.print((float)DHT11.humidity, 2);
  Serial.print("Temperature (°C): ");
  Serial.println((float)DHT11.temperature, 2);
  lcd.setCursor(0, 1);
  lcd.print("Temp C:");
  lcd.print((float)DHT11.temperature, 2);
  Serial.print("Temperature (°F): ");
  Serial.println(Fahrenheit(DHT11.temperature), 2);

  Serial.print("Temperature (°K): ");
  Serial.println(Kelvin(DHT11.temperature), 2);

  Serial.print("Dew Point (°C): ");
  Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));

  Serial.print("Dew PointFast (°C): ");
  Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));

  delay(2000);
}
//
// END OF FILE
//

卡库脆香米

图中圆圆的那个原件是什么啊？而且你这个1602是怎么连接的啊 ？望指教 ！感谢 感谢

galaxy

>>>图中圆圆的那个原件是什么啊？

在1602的屏幕上方那個圓圓的...是 VR (可變電阻,電位計)


>>>而且你这个1602是怎么连接的啊 ？

參考這一帖 http://www.geek-workshop.com/thread-78-1-1.html

在二樓的程序中

LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

這就是1602的接線
LiquidCrystal lcd(12, 11, 5, 4, 3, 2); // (RS , Enable , D4 , D5 , D6  ,D7 )

saybey

Serial.println(Kelvin(DHT11.temperature), 2);

把2变成0  值后面的。00就没有了

baiyksygg

卡库脆香米 发表于 2017-10-7 09:47
图中圆圆的那个原件是什么啊？而且你这个1602是怎么连接的啊 ？望指教 ！感谢 感谢

电位器，调对比度的

卡库脆香米

感谢楼主 ！！！！