极客工坊

 找回密码
 注册

QQ登录

只需一步,快速开始

查看: 41073|回复: 1

Arduino 平衡车 MPU6050 L298N

[复制链接]
发表于 2018-2-12 17:35:54 | 显示全部楼层 |阅读模式
本帖最后由 天上人间 于 2018-2-12 17:35 编辑

L298N电机驱动模块
  • 图示:

  • 驱动电压5v~35v, 逻辑电压5v. 内置的78M05通过驱动电源部分取电工作, 当使用大于12V驱动电压的时候,为了避免稳压芯片损坏, 请使用外置的5V逻辑供电。
  • ENA:OUT1和OUT2的使能端,默认情况下,跳线帽接上时,高电平有效,低电平禁止;如果需要PWM调速,就需要拔掉跳线帽.

驱动直流电机
  • 本模块是2路的H桥驱动,所以可以同时驱动两个电机
  • 使能ENA ENB之后
  • 可以分别从IN1 IN2输入PWM信号驱动电机1的转速和方向
  • 可以分别从IN3 IN4输入PWM信号驱动电机2的转速和方向
  • 图示:

驱动步进电机
  • 图示:

L298N驱动板介绍:
  • 图示1:
    图示2:

  • 6,7帽拔掉后,插在下面的针上,int1,int2控制左输出1。
  • 如果L298N和arduino使用不同的电源供电的话,那么需要将arduino的GND和模块上的GND连接在一起,只有这样单片机上过来的逻辑信号才有个参考0点。此点非常重要,请大家注意.

L298N驱动板接线方法
  • 方式1:ENA插帽拔掉,通过IN1和IN2控制电机转动方向(正转或反转), 通过ENA控制电机的转速。
测试电机开始转的PWM值    1、PWM值小,电机不转。
     2、 PWM就是脉宽调制器,通过调制器给电机提供一个具有一定频率的脉冲宽度可调的脉冲电。脉冲宽度越大即占空比越大,提供给电机的平均电压越大,电机转速就高。反之脉冲宽度越小,则占空比越越小。提供给电机的平均电压越小,电机转速就低。 PWM不管是高电平还是低电平时电机都是转动的,电机的转速取决于平均电压!
     注:当电机负载较轻时,PWM 不到100% 就可以让电机达到最快转速,之后 PWM 的改变就不再影响电机速度了(这个概念还是在玩 LEGO 时看到的,LEGO 的 RCX 只能通过 PWM 改变电机速度,所以有时需要额外增加阻力以使得转速可以随 PWM 的变化而变化)。
  1. int output;
  2. void setup()
  3. {

  4.   Serial.begin(9600);

  5.   for (int i=5; i<=10; i++)//将10,5,6,7,8,9定义为输出口
  6.   {
  7.     pinMode(i, OUTPUT);
  8.   }

  9. }

  10. void loop()
  11. {  
  12.                                                                   
  13. for(output=1;output<255;output++){
  14.   if (output > 0)
  15.   {
  16.     digitalWrite(7, LOW);
  17.     digitalWrite(8, HIGH);
  18.     digitalWrite(9,LOW);
  19.     digitalWrite(10, HIGH);
  20.   }
  21.   if (output < 0)
  22.   {
  23.     digitalWrite(7, HIGH);
  24.     digitalWrite(8, LOW);
  25.     digitalWrite(9,HIGH);
  26.     digitalWrite(10, LOW);
  27.   }
  28.   
  29.     //output = min(200,abs(40*angleG));//此函数输出较小值,将PWM最大值限定在200,下面起步补偿55
  30.    
  31.     analogWrite(5, output);//左右轮都补偿起步PWM值,左右轮电机可能不一致,有可能5针ENA右轮多补偿
  32.     analogWrite(6, output);//output的值在100左右时,香蕉电机才起动,汗!。
  33.    
  34.     delay(1000);
  35.     Serial.print("output = ");
  36.     Serial.println(output);
  37.     }
  38. }
复制代码
MPU6050


  •     MPU6050是一种非常流行的空间运动传感器芯片,可以获取器件当前的三个加速度分量和三个旋转角速度。
  •     MPU6050的数据接口用的是I2C总线协议,因此我们需要Wire程序库的帮助来实现Arduino与MPU6050之间的通信。请先确认你的Arduino编程环境中已安装Wire库。
  • Wire库的官方文档(http://www.arduino.cc/en/Reference/Wire)中指出:在UNO板子上,SDA接口对应的是A4引脚,SCL对应的是A5引脚。MPU6050需要5V的电源,可由UNO板直接供电。按照下图连线。
  • MPU6050 引脚说明
    VCC             3.3-5V(内部有稳压芯片)
    GND             地线
    SCL              MPU6050作为从机时IIC时钟线
    SDA              MPU6050作为从机时IIC数据线
    XCL               MPU6050作为主机时IIC时钟线
    XDA              MPU6050作为主机时IIC数据线
    AD0              地址管脚,该管脚决定了IIC地址的最低一位
    INT                中断引脚

    (紫色线是中断线)

程序实现
  • 首先要更新I2C库
  • 在GITHUB找到的I2C库
  • (程序来源: https://github.com/jrowberg/i2cdevlib)打开,把Arduino文件夹里的I2Cdev,MPU6050文件夹复制到Arduino IDE的库文件夹里
  • (默认的路径是这个 C:\Program Files (x86)\Arduino\libraries)(本人把这些文件放在了源文件.ino所在文件夹)
  • 在GITHUB找到的卡尔曼滤波程序(程序来源: https://github.com/wjjun/MPU6050_Kalman
  • 把程序上传到板子上,打开串口监视器,就可以看到一堆堆的数据了


卡尔曼滤波器
简单来说,卡尔曼滤波器是一个“optimal recursive data processing algorithm(最优化自回归数据处理算法)”。对于解决很大部分的问题,他是最优,效率最高甚至是最有用的。他的广泛应用已经超过30年,包括机器人导航,控制,传感器数据融合甚至在军事方面的雷达系统以及导弹追踪等等。近来更被应用于计算机图像处理,例如头脸识别,图像分割,图像边缘检测等等。
卡尔曼滤波器的介绍 :
为了可以更加容易的理解卡尔曼滤波器,这里会应用形象的描述方法来讲解,而不是像大多数参考书那样罗列一大堆的数学公式和数学符号。但是,他的5条公式是其核心内容。结合现代的计算机,其实卡尔曼的程序相当的简单,只要你理解了他的那5条公式
在介绍他的5条公式之前,先让我们来根据下面的例子一步一步的探索。
假设我们要研究的对象是一个房间的温度。根据你的经验判断,这个房间的温度是恒定的,也就是下一分钟的温度等于现在这一分钟的温度(假设我们用一分钟来做时间单位)。假设你对你的经验不是100%的相信,可能会有上下偏差几度。我们把这些偏差看成是高斯白噪声(White Gaussian Noise),也就是这些偏差跟前后时间是没有关系的而且符合高斯分布(Gaussian Distribution)。另外,我们在房间里放一个温度计,但是这个温度计也不准确的,测量值会比实际值偏差。我们也把这些偏差看成是高斯白噪声。
好了,现在对于某一分钟我们有两个有关于该房间的温度值:你根据经验的预测值(系统的预测值)和温度计的值(测量值)。下面我们要用这两个值结合他们各自的噪声来估算出房间的实际温度值。
假如我们要估算k时刻的实际温度值。首先你要根据k-1时刻的温度值,来预测k时刻的温度。因为你相信温度是恒定的,所以你会得到k时刻的温度预测值是跟k-1时刻一样的,假设是23度,同时该值的高斯噪声的偏差是5度(5是这样得到的:如果k-1时刻估算出的最优温度值的偏差是3,你对自己预测的不确定度是4度,他们平方相加再开方,就是5)。然后,你从温度计那里得到了k时刻的温度值,假设是25度,同时该值的偏差是4度。
由于我们用于估算k时刻的实际温度有两个温度值,分别是23度和25度。究竟实际温度是多少呢?相信自己还是相信温度计呢?究竟相信谁多一点,我们可以用他们的协方差(covariance)来判断。因为Kg=5^2/(5^2+4^2),所以Kg=0.61,我们可以估算出k时刻的实际温度值是:23+0.61*(25-23)=24.22度。可以看出,因为温度计的协方差(covariance)比较小(比较相信温度计),所以估算出的最优温度值偏向温度计的值。
现在我们已经得到k时刻的最优温度值了,下一步就是要进入k+1时刻,进行新的最优估算。到现在为止,好像还没看到什么自回归的东西出现。对了,在进入k+1时刻之前,我们还要算出k时刻那个最优值(24.22度)的偏差。算法如下:((1-Kg)*5^2)^0.5=3.12。这里的5就是上面的k时刻你预测的那个23度温度值的偏差,得出的3.12就是进入k+1时刻以后k时刻估算出的最优温度值的偏差(对应于上面的3)。
就是这样,卡尔曼滤波器就不断的把(协方差(covariance)递归,从而估算出最优的温度值。他运行的很快,而且它只保留了上一时刻的协方差(covariance)。上面的Kg,就是卡尔曼增益(Kalman Gain)。他可以随不同的时刻而改变他自己的值,是不是很神奇!

  1. //卡尔曼滤波参数与函数
  2. float dt=0.005;//注意:dt的取值为kalman滤波器采样时间
  3. float angle, angle_dot;//角度和角速度
  4. float P[2][2] = {{ 1, 0 },
  5.               { 0, 1 }};
  6. float Pdot[4] ={ 0,0,0,0};
  7. float Q_angle=0.001, Q_gyro=0.005; //角度数据置信度,角速度数据置信度
  8. float R_angle=0.5 ,C_0 = 1;
  9. float q_bias, angle_err, PCt_0, PCt_1, E, K_0, K_1, t_0, t_1;


  10. //卡尔曼滤波
  11. void Kalman_Filter(float angle_m, float gyro_m)//angleAx 和 gyroGy
  12. {
  13. angle+=(gyro_m-q_bias) * dt;
  14. angle_err = angle_m - angle;
  15. Pdot[0]=Q_angle - P[0][1] - P[1][0];
  16. Pdot[1]=- P[1][1];
  17. Pdot[2]=- P[1][1];
  18. Pdot[3]=Q_gyro;
  19. P[0][0] += Pdot[0] * dt;
  20. P[0][1] += Pdot[1] * dt;
  21. P[1][0] += Pdot[2] * dt;
  22. P[1][1] += Pdot[3] * dt;
  23. PCt_0 = C_0 * P[0][0];
  24. PCt_1 = C_0 * P[1][0];
  25. E = R_angle + C_0 * PCt_0;
  26. K_0 = PCt_0 / E;
  27. K_1 = PCt_1 / E;
  28. t_0 = PCt_0;
  29. t_1 = C_0 * P[0][1];
  30. P[0][0] -= K_0 * t_0;
  31. P[0][1] -= K_0 * t_1;
  32. P[1][0] -= K_1 * t_0;
  33. P[1][1] -= K_1 * t_1;
  34. angle += K_0 * angle_err; //最优角度
  35. q_bias += K_1 * angle_err;
  36. angle_dot = gyro_m-q_bias;//最优角速度
  37. }
复制代码


陀螺仪 简单读取
  1. #include "Wire.h"
  2. #include "I2Cdev.h"
  3. #include "MPU6050.h"
  4. MPU6050 accelgyro;
  5. int16_t ax, ay, az;
  6. int16_t gx, gy, gz;
  7. bool blinkState = false;
  8. void setup() {
  9.     Wire.begin();
  10.     Serial.begin(38400);
  11.     accelgyro.initialize();
  12. }
  13. void loop() {
  14.     accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz);
  15.     Serial.print("a/g:\t");
  16.     Serial.print(ax); Serial.print("\t");
  17.     Serial.print(ay); Serial.print("\t");
  18.     Serial.print(az); Serial.print("\t");
  19.     Serial.print(gx); Serial.print("\t");
  20.     Serial.print(gy); Serial.print("\t");
  21.     Serial.println(gz);
  22.     blinkState = !blinkState;
  23. }
复制代码

Arduino uno + mpu6050 陀螺仪 运用卡尔曼滤波姿态解算
本例程输出XYZ的角度,正负90度。
运用卡尔曼滤波算法解算姿态。

  1. #include "Wire.h"  
  2. #include "I2Cdev.h"  
  3. #include "MPU6050.h"  
  4.   
  5. MPU6050 accelgyro;  
  6.   
  7. unsigned long now, lastTime = 0;  
  8. float dt;                                   //微分时间  
  9.   
  10. int16_t ax, ay, az, gx, gy, gz;             //加速度计陀螺仪原始数据  
  11. float aax=0, aay=0,aaz=0, agx=0, agy=0, agz=0;    //角度变量  
  12. long axo = 0, ayo = 0, azo = 0;             //加速度计偏移量  
  13. long gxo = 0, gyo = 0, gzo = 0;             //陀螺仪偏移量  
  14.   
  15. float pi = 3.1415926;  
  16. float AcceRatio = 16384.0;                  //加速度计比例系数  
  17. float GyroRatio = 131.0;                    //陀螺仪比例系数  
  18.   
  19. uint8_t n_sample = 8;                       //加速度计滤波算法采样个数  
  20. float aaxs[8] = {0}, aays[8] = {0}, aazs[8] = {0};         //x,y轴采样队列  
  21. long aax_sum, aay_sum,aaz_sum;                      //x,y轴采样和  
  22.   
  23. float a_x[10]={0}, a_y[10]={0},a_z[10]={0} ,g_x[10]={0} ,g_y[10]={0},g_z[10]={0}; //加速度计协方差计算队列  
  24. float Px=1, Rx, Kx, Sx, Vx, Qx;             //x轴卡尔曼变量  
  25. float Py=1, Ry, Ky, Sy, Vy, Qy;             //y轴卡尔曼变量  
  26. float Pz=1, Rz, Kz, Sz, Vz, Qz;             //z轴卡尔曼变量  
  27.   
  28. void setup()  
  29. {  
  30.     Wire.begin();  
  31.     Serial.begin(115200);  
  32.   
  33.     accelgyro.initialize();                 //初始化  
  34.   
  35.     unsigned short times = 200;             //采样次数  
  36.     for(int i=0;i<times;i++)  
  37.     {  
  38.         accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz); //读取六轴原始数值  
  39.         axo += ax; ayo += ay; azo += az;      //采样和  
  40.         gxo += gx; gyo += gy; gzo += gz;  
  41.       
  42.     }  
  43.       
  44.     axo /= times; ayo /= times; azo /= times; //计算加速度计偏移  
  45.     gxo /= times; gyo /= times; gzo /= times; //计算陀螺仪偏移  
  46. }  
  47.   
  48. void loop()  
  49. {  
  50.     unsigned long now = millis();             //当前时间(ms)  
  51.     dt = (now - lastTime) / 1000.0;           //微分时间(s)  
  52.     lastTime = now;                           //上一次采样时间(ms)  
  53.   
  54.     accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz); //读取六轴原始数值  
  55.   
  56.     float accx = ax / AcceRatio;              //x轴加速度  
  57.     float accy = ay / AcceRatio;              //y轴加速度  
  58.     float accz = az / AcceRatio;              //z轴加速度  
  59.   
  60.     aax = atan(accy / accz) * (-180) / pi;    //y轴对于z轴的夹角  
  61.     aay = atan(accx / accz) * 180 / pi;       //x轴对于z轴的夹角  
  62.     aaz = atan(accz / accy) * 180 / pi;       //z轴对于y轴的夹角  
  63.   
  64.     aax_sum = 0;                              // 对于加速度计原始数据的滑动加权滤波算法  
  65.     aay_sum = 0;  
  66.     aaz_sum = 0;  
  67.    
  68.     for(int i=1;i<n_sample;i++)  
  69.     {  
  70.         aaxs[i-1] = aaxs[i];  
  71.         aax_sum += aaxs[i] * i;  
  72.         aays[i-1] = aays[i];  
  73.         aay_sum += aays[i] * i;  
  74.         aazs[i-1] = aazs[i];  
  75.         aaz_sum += aazs[i] * i;  
  76.       
  77.     }  
  78.       
  79.     aaxs[n_sample-1] = aax;  
  80.     aax_sum += aax * n_sample;  
  81.     aax = (aax_sum / (11*n_sample/2.0)) * 9 / 7.0; //角度调幅至0-90°  
  82.     aays[n_sample-1] = aay;                        //此处应用实验法取得合适的系数  
  83.     aay_sum += aay * n_sample;                     //本例系数为9/7  
  84.     aay = (aay_sum / (11*n_sample/2.0)) * 9 / 7.0;  
  85.     aazs[n_sample-1] = aaz;   
  86.     aaz_sum += aaz * n_sample;  
  87.     aaz = (aaz_sum / (11*n_sample/2.0)) * 9 / 7.0;  
  88.   
  89.     float gyrox = - (gx-gxo) / GyroRatio * dt; //x轴角速度  
  90.     float gyroy = - (gy-gyo) / GyroRatio * dt; //y轴角速度  
  91.     float gyroz = - (gz-gzo) / GyroRatio * dt; //z轴角速度  
  92.     agx += gyrox;                             //x轴角速度积分  
  93.     agy += gyroy;                             //x轴角速度积分  
  94.     agz += gyroz;  
  95.       
  96.     /* kalman start */  
  97.     Sx = 0; Rx = 0;  
  98.     Sy = 0; Ry = 0;  
  99.     Sz = 0; Rz = 0;  
  100.       
  101.     for(int i=1;i<10;i++)  
  102.     {                 //测量值平均值运算  
  103.         a_x[i-1] = a_x[i];                      //即加速度平均值  
  104.         Sx += a_x[i];  
  105.         a_y[i-1] = a_y[i];  
  106.         Sy += a_y[i];  
  107.         a_z[i-1] = a_z[i];  
  108.         Sz += a_z[i];  
  109.       
  110.     }  
  111.       
  112.     a_x[9] = aax;  
  113.     Sx += aax;  
  114.     Sx /= 10;                                 //x轴加速度平均值  
  115.     a_y[9] = aay;  
  116.     Sy += aay;  
  117.     Sy /= 10;                                 //y轴加速度平均值  
  118.     a_z[9] = aaz;  
  119.     Sz += aaz;  
  120.     Sz /= 10;  
  121.   
  122.     for(int i=0;i<10;i++)  
  123.     {  
  124.         Rx += sq(a_x[i] - Sx);  
  125.         Ry += sq(a_y[i] - Sy);  
  126.         Rz += sq(a_z[i] - Sz);  
  127.       
  128.     }  
  129.       
  130.     Rx = Rx / 9;                              //得到方差  
  131.     Ry = Ry / 9;                          
  132.     Rz = Rz / 9;  
  133.    
  134.     Px = Px + 0.0025;                         // 0.0025在下面有说明...  
  135.     Kx = Px / (Px + Rx);                      //计算卡尔曼增益  
  136.     agx = agx + Kx * (aax - agx);             //陀螺仪角度与加速度计速度叠加  
  137.     Px = (1 - Kx) * Px;                       //更新p值  
  138.   
  139.     Py = Py + 0.0025;  
  140.     Ky = Py / (Py + Ry);  
  141.     agy = agy + Ky * (aay - agy);   
  142.     Py = (1 - Ky) * Py;  
  143.    
  144.     Pz = Pz + 0.0025;  
  145.     Kz = Pz / (Pz + Rz);  
  146.     agz = agz + Kz * (aaz - agz);   
  147.     Pz = (1 - Kz) * Pz;  
  148.   
  149.     /* kalman end */  
  150.   
  151.     Serial.print(agx);Serial.print(","); //要看MPU6050如何放置<span style="color: rgb(0, 0, 0); font-family: Arial, Helvetica, sans-serif; font-size: 12px; background-color: rgb(255, 255, 255);">翻转角 俯仰角和偏航角</span>
  152.     Serial.print(agy);Serial.print(",");  
  153.     Serial.print(agz);Serial.println();  
  154.       
  155. }  
复制代码

PID控制
    1、比例(P)控制
    比例控制是一种最简单的控制方式。其控制器的输出与输入误差信号成比例关系。当仅有比例控制时系统输出存在稳态误差(Steady-state error)。
   2、 积分(I)控制
    在积分控制中,控制器的输出与输入误差信号的积分成正比关系。对一个自动控制系统,如果在进入稳态后存在稳态误差,则称这个控制系统是有稳态误差的或简称有差系统(System with Steady-state Error)。为了消除稳态误差,在控制器中必须引入“积分项”。积分项对误差取决于时间的积分,随着时间的增加,积分项会增大。这样,即便误差很小,积分项也会随着时间的增加而加大,它推动控制器的输出增大使稳态误差进一步减小,直到等于零。因此,比例+积分(PI)控制器,可以使系统在进入稳态后无稳态误差。
    3、微分(D)控制
    在微分控制中,控制器的输出与输入误差信号的微分(即误差的变化率)成正比关系。自动控制系统在克服误差的调节过程中可能会出现振荡甚至失稳。其原因是由于存在有较大惯性组件(环节)或有滞后(delay)组件,具有抑制误差的作用,其变化总是落后于误差的变化。解决的办法是使抑制误差的作用的变化“超前”,即在误差接近零时,抑制误差的作用就应该是零。这就是说,在控制器中仅引入 “比例”项往往是不够的,比例项的作用仅是放大误差的幅值,而目前需要增加的是“微分项”,它能预测误差变化的趋势,这样,具有比例+微分的控制器,就能够提前使抑制误差的控制作用等于零,甚至为负值,从而避免了被控量的严重超调。所以对有较大惯性或滞后的被控对象,比例+微分(PD)控制器能改善系统在调节过程中的动态特性。

最终用的这个代码,站的不好,只站一会儿

  1. //copyright by kaiser 20140521 V1.0
  2. /////////////////////////////////////////////////////////////////////////////////////////////////////
  3. #include "Wire.h"            //serial
  4. #include "I2Cdev.h"          //IIC
  5. #include "MPU6050.h"         //acc&gyro Sensor
  6. //Define Variables we'll be connecting to
  7. char val='s';int Speed_need=0;int Turn_need=0;
  8. float speeds,speeds_filter, positions;
  9. float diff_speeds,diff_speeds_all;
  10. ////////////////////PID parameter///////////////////////////////////////
  11. double Output=0;
  12. float Kp=10,Kd=0.06,Ksp = 2.8,Ksi = 0.11;        //

  13. ////////////////////////////////////////////////
  14. MPU6050 accelgyro;
  15. int16_t ax, ay, az;
  16. int16_t gx, gy, gz;
  17. /********************角度参数**************/
  18. float Gyro_y;            //Y轴陀螺仪数据暂存
  19. float Angle_ax;          //由加速度计算的倾斜角度
  20. float Angle;             //小车最终倾斜角度
  21. //int Setpoint=0;
  22. ////////////////////////////////////////Pin assignment///////////////////////////////////////
  23. int PinA_right= 2; //interrupt 0
  24. int PinA_left= 3; //interrupt 1
  25. int E_left =6;//ENA
  26. int M_right =7;
  27. int M_right2=8;
  28. int E_right =5; //ENB
  29. int M_left =9;  
  30. int M_left2 =10;
  31. //////////////////////////////////////////////////////////////////////////////
  32. int PWM_right=0; int PWM_left=0;
  33. int PWM_left_least=87; int PWM_right_least=88;//left:77,right:78
  34. ///////////////////////////////interrupt for Speed/////////////////////////////////
  35. int count_right =0;
  36. int count_left  =0;
  37. int old_time=0;
  38. int flag;
  39. void Code_right(){  if(Output>=0){count_right += 1;}else{count_right -= 1;} }//if only +,can't stand up 编码器码盘计数加一
  40. void Code_left(){  if(Output>=0){count_left += 1;} else{count_left -= 1;}}// 编码器码盘计数加一   
  41. /////////////////////////Right&Left&Stop///////////////////////////////////////////////
  42. void SetMotorVoltage(int nLeftVol, int nRightVol) {
  43.     if(nLeftVol >=0)
  44.   {  digitalWrite(M_left,LOW);
  45.      digitalWrite(M_left2,HIGH);
  46.    } else {      
  47.      digitalWrite(M_left,HIGH);
  48.      digitalWrite(M_left2,LOW);
  49.      nLeftVol=-nLeftVol;
  50.    }
  51.     if(nRightVol >= 0) {
  52.      digitalWrite(M_right,LOW);
  53.      digitalWrite(M_right2,HIGH);
  54.     } else {
  55.      digitalWrite(M_right,HIGH);
  56.      digitalWrite(M_right2,LOW);
  57.     nRightVol=-nRightVol;
  58.   }
  59.     if(nLeftVol>255) { nLeftVol = 255 ; }   //防止PWM值超过255
  60.     if(nRightVol>255) { nRightVol = 255 ; }//防止PWM值超过255
  61.     analogWrite(E_left,nLeftVol);
  62.     analogWrite(E_right,nRightVol);
  63. }

  64. /////////////////////////////////////////////////////////////////////////////////////////////
  65. void Angle_Calcu(void)         {
  66.         Angle_ax = (ax+1942)/238.2 ;   //去除零点偏移1942,//16384*3.14/1.2*180//弧度转换为度,
  67.               Gyro_y = -(gy-119.58)/16.4;         //去除零点偏移119,2000deg/s 16.4 LSB/(deg/s)250---131 ,负号为方向处理
  68.         //Serial.print("Angle_ax,Angle_gy");Serial.print(Angle_ax);Serial.println(Angle_gy);
  69.         Angle=0.97*(Angle+Gyro_y*0.0005)+0.03*Angle_ax;
  70.         //Kalman_Filter(Angle_ax,Gyro_y);       //卡尔曼滤波计算倾角                                                                                                         
  71. }   

  72. void setup()
  73. {
  74.     Wire.begin();
  75.     Serial.begin(9600);  
  76.    ///////////////////////////////////////////////////////////////////
  77.     accelgyro.reset();//reset
  78.     delay(1);
  79.     accelgyro.setClockSource(MPU6050_CLOCK_PLL_YGYRO);//PLL with Y Gyro reference*/
  80.     accelgyro.setFullScaleGyroRange(MPU6050_GYRO_FS_2000);//0x1B Value 0x18 2000°/s
  81.     accelgyro.setFullScaleAccelRange(MPU6050_ACCEL_FS_4);//0x1C Value 0x18 16g
  82.     accelgyro.setDLPFMode(MPU6050_DLPF_BW_5);//0x06 means acc 5Hz delay19.0ms Gyro 5Hz delay 18.6ms
  83.     accelgyro.setTempSensorEnabled(true);//disable temsensor
  84.     accelgyro.setSleepEnabled(false);
  85.     Serial.println("Testing device connections...");
  86.     Serial.println(accelgyro.testConnection() ? "MPU6050 connection successful" : "MPU6050 connection failed");
  87.    ////////////////////////pin mode////////////////////////////////////////
  88.    pinMode(E_right, OUTPUT); pinMode(M_right, OUTPUT);pinMode(M_right2, OUTPUT);  //right
  89.    pinMode(E_left, OUTPUT);  pinMode(M_left, OUTPUT);pinMode(M_left2, OUTPUT);  //left
  90.    pinMode(PinA_right,INPUT);pinMode(PinA_left,INPUT);// in 0 in 1
  91.    Serial.println("Pin mode ...");
  92.    /////////////////////////////interrupt/////////////////////////////////////////////
  93.    attachInterrupt(0, Code_right, FALLING);attachInterrupt(1, Code_left, FALLING);
  94.    
  95. }

  96. void loop()
  97. {
  98.    if (Serial.available() > 0){val = Serial.read();Serial.println(val);}
  99.      switch(val){
  100.      case 'a':Speed_need=30;Turn_need=0;positions=80;break;//Go
  101.      case 'b':Speed_need=10;Turn_need=-10;positions=10;break;//right
  102.      case 'c':Speed_need=10;Turn_need=10;positions=10;break;//left
  103.      case 'd':Speed_need=0;Turn_need=0;positions=0;break;
  104.      default:Speed_need=0;Turn_need=0;positions=0;break;}//stop
  105.    
  106.      //Speed_need=30;Turn_need=0;positions=80;  
  107.      //SetMotorVoltage(255,255);
  108.     //Kp=15,Kd=0.09,Ksp = 2.8,Ksi = 0.11;
  109.          //Serial.print("count_left");Serial.println(count_left);
  110.     accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz);
  111.     Angle_Calcu();
  112.     //Serial.print("Angle");Serial.println(Angle);
  113.     PWM_Calcu();
  114.   
  115.    //if(millis()-old_time>=500){ Serial.print("count_right");Serial.print(count_right);Serial.print("count_left");Serial.println(count_left);old_time=millis();count_right=0;count_left=0;}     
  116. }
  117. void PWM_Calcu(void)
  118. {
  119.   if (abs(Angle)>40)
  120.     {SetMotorVoltage(0,0);}//角度大于45度 停止PWM输出
  121.     else
  122.     { //Speed_need=30;Turn_need=0;positions=80;
  123.       //////////////////////
  124.       speeds=(count_left + count_right)*0.5;
  125.       diff_speeds = count_left - count_right;
  126.       diff_speeds_all += diff_speeds;
  127.       speeds_filter *=0.85;  //一阶互补滤波
  128.       speeds_filter +=speeds*0.15;
  129.       positions += speeds_filter;
  130.       positions += Speed_need;
  131.       positions = constrain(positions, -2300, 2300);//抗积分饱和
  132.       ////////////////////
  133.       Output=Kp*Angle+Kd*Gyro_y+ Ksp*speeds_filter + Ksi*positions ;
  134.       //Serial.print("Output");Serial.println(Output);
  135.       if(Turn_need==0){PWM_right=Output-diff_speeds_all;
  136.       PWM_left=Output+diff_speeds_all;}
  137.       
  138.       PWM_right=Output+Turn_need;
  139.       PWM_left=Output-Turn_need;
  140.       
  141.       if(PWM_right>=0){PWM_right+=PWM_right_least;}else{PWM_right-=PWM_right_least;}
  142.       if(PWM_left>=0){PWM_left+=PWM_left_least;}else{PWM_left-=PWM_left_least;}

  143.       SetMotorVoltage(PWM_left,PWM_right);}
  144.        count_left = 0;
  145.   count_right = 0;
  146. }

复制代码
修改了几个地方

  1. //copyright by kaiser 20140521 V1.0
  2. /////////////////////////////////////////////////////////////////////////////////////////////////////
  3. #include "Wire.h"            //serial
  4. #include "I2Cdev.h"          //IIC
  5. #include "MPU6050.h"         //acc&gyro Sensor
  6. //Define Variables we'll be connecting to
  7. char val='s';int Speed_need=0;int Turn_need=0;
  8. float speeds,speeds_filter, positions;
  9. float diff_speeds,diff_speeds_all;
  10. ////////////////////PID parameter///////////////////////////////////////
  11. double Output=0;
  12. float Kp=10,Kd=0.06,Ksp = 2.8,Ksi = 0.11;        //

  13. ////////////////////////////////////////////////
  14. MPU6050 accelgyro;
  15. int16_t ax, ay, az;
  16. int16_t gx, gy, gz;
  17. /********************角度参数**************/
  18. float Gyro_y;            //Y轴陀螺仪数据暂存
  19. float Angle_ax;          //由加速度计算的倾斜角度
  20. float Angle;             //小车最终倾斜角度
  21. //int Setpoint=0;
  22. ////////////////////////////////////////Pin assignment///////////////////////////////////////
  23. int PinA_right= 2; //interrupt 0
  24. int PinA_left= 3; //interrupt 1
  25. int E_left =6;//ENA
  26. int M_right =7;
  27. int M_right2=8;
  28. int E_right =5; //ENB
  29. int M_left =9;  
  30. int M_left2 =10;
  31. //////////////////////////////////////////////////////////////////////////////
  32. int PWM_right=0; int PWM_left=0;
  33. int PWM_left_least=87; int PWM_right_least=88;//left:77,right:78
  34. ///////////////////////////////interrupt for Speed/////////////////////////////////
  35. int count_right =0;
  36. int count_left  =0;
  37. int old_time=0;
  38. int flag;
  39. int moto=85;
  40. int qd=0;
  41. void Code_right(){  if(Output>=0){count_right += 1;}else{count_right -= 1;} }//if only +,can't stand up 编码器码盘计数加一
  42. void Code_left(){  if(Output>=0){count_left += 1;} else{count_left -= 1;}}// 编码器码盘计数加一   
  43. /////////////////////////Right&Left&Stop///////////////////////////////////////////////
  44. void SetMotorVoltage(int nLeftVol, int nRightVol) {
  45.     if(nLeftVol >=0)
  46.   {  digitalWrite(M_left,LOW);
  47.      digitalWrite(M_left2,HIGH);
  48.    
  49.    } else {      
  50.      digitalWrite(M_left,HIGH);
  51.      digitalWrite(M_left2,LOW);
  52.      nLeftVol=-nLeftVol;
  53.    }
  54.     if(nRightVol >= 0) {
  55.      digitalWrite(M_right,LOW);
  56.      digitalWrite(M_right2,HIGH);
  57.      
  58.     } else {
  59.      digitalWrite(M_right,HIGH);
  60.      digitalWrite(M_right2,LOW);
  61.     nRightVol=-nRightVol;
  62.   }
  63.    nLeftVol = nLeftVol+moto ;nRightVol = nRightVol+moto ;
  64.     if(nLeftVol>255) { nLeftVol = 255 ; }   //防止PWM值超过255
  65.     if(nRightVol>255) { nRightVol = 255 ; }//防止PWM值超过255
  66.    
  67.     if(qd==1) { nLeftVol = 0 ;nRightVol = 0 ; }   //已倒,PWM值为0
  68.   
  69.      Serial.println(nRightVol);
  70.     analogWrite(E_left,nLeftVol);
  71.     analogWrite(E_right,nRightVol);
  72. }

  73. /////////////////////////////////////////////////////////////////////////////////////////////
  74. void Angle_Calcu(void)         {
  75.        Angle_ax = (ax-1300)/238.2 ;   //去除零点偏移1942,//16384*3.14/1.2*180//弧度转换为度,
  76.               Gyro_y = -(gy-180)/16.4;         //去除零点偏移119,2000deg/s 16.4 LSB/(deg/s)250---131 ,负号为方向处理
  77.         //Angle_ax = (ax)/238.2 ;
  78.          //Gyro_y = -(gy)/16.4;   
  79.         //Serial.print("Angle_ax,Angle_gy");Serial.print(Angle_ax);Serial.println(Angle_gy);
  80.         Angle=0.97*(Angle+Gyro_y*0.0005)+0.03*Angle_ax;
  81.          
  82.         //Kalman_Filter(Angle_ax,Gyro_y);       //卡尔曼滤波计算倾角   
  83.        //Serial.println(Angle);                                                                                                      
  84. }   


  85. float dt=0.005;//注意:dt的取值为kalman滤波器采样时间
  86. float angle, angle_dot;//角度和角速度
  87. float P[2][2] = {{ 1, 0 },
  88.               { 0, 1 }};
  89. float Pdot[4] ={ 0,0,0,0};
  90. float Q_angle=0.001, Q_gyro=0.005; //角度数据置信度,角速度数据置信度
  91. float R_angle=0.5 ,C_0 = 1;
  92. float q_bias, angle_err, PCt_0, PCt_1, E, K_0, K_1, t_0, t_1;


  93. //卡尔曼滤波
  94. void Kalman_Filter(float angle_m, float gyro_m)//angleAx 和 gyroGy
  95. {
  96. angle+=(gyro_m-q_bias) * dt;
  97. angle_err = angle_m - angle;
  98. Pdot[0]=Q_angle - P[0][1] - P[1][0];
  99. Pdot[1]=- P[1][1];
  100. Pdot[2]=- P[1][1];
  101. Pdot[3]=Q_gyro;
  102. P[0][0] += Pdot[0] * dt;
  103. P[0][1] += Pdot[1] * dt;
  104. P[1][0] += Pdot[2] * dt;
  105. P[1][1] += Pdot[3] * dt;
  106. PCt_0 = C_0 * P[0][0];
  107. PCt_1 = C_0 * P[1][0];
  108. E = R_angle + C_0 * PCt_0;
  109. K_0 = PCt_0 / E;
  110. K_1 = PCt_1 / E;
  111. t_0 = PCt_0;
  112. t_1 = C_0 * P[0][1];
  113. P[0][0] -= K_0 * t_0;
  114. P[0][1] -= K_0 * t_1;
  115. P[1][0] -= K_1 * t_0;
  116. P[1][1] -= K_1 * t_1;
  117. angle += K_0 * angle_err; //最优角度
  118. q_bias += K_1 * angle_err;
  119. angle_dot = gyro_m-q_bias;//最优角速度
  120. }

  121. void setup()
  122. {
  123.     Wire.begin();
  124.     Serial.begin(9600);  
  125.    ///////////////////////////////////////////////////////////////////
  126.     accelgyro.reset();//reset
  127.     delay(500);
  128.     accelgyro.setClockSource(MPU6050_CLOCK_PLL_YGYRO);//PLL with Y Gyro reference*/
  129.     accelgyro.setFullScaleGyroRange(MPU6050_GYRO_FS_2000);//0x1B Value 0x18 2000°/s
  130.     accelgyro.setFullScaleAccelRange(MPU6050_ACCEL_FS_4);//0x1C Value 0x18 16g
  131.     accelgyro.setDLPFMode(MPU6050_DLPF_BW_5);//0x06 means acc 5Hz delay19.0ms Gyro 5Hz delay 18.6ms
  132.     accelgyro.setTempSensorEnabled(true);//disable temsensor
  133.     accelgyro.setSleepEnabled(false);
  134.     Serial.println("Testing device connections...");
  135.     Serial.println(accelgyro.testConnection() ? "MPU6050 connection successful" : "MPU6050 connection failed");
  136.    ////////////////////////pin mode////////////////////////////////////////
  137.    pinMode(E_right, OUTPUT); pinMode(M_right, OUTPUT);pinMode(M_right2, OUTPUT);  //right
  138.    pinMode(E_left, OUTPUT);  pinMode(M_left, OUTPUT);pinMode(M_left2, OUTPUT);  //left
  139.    pinMode(PinA_right,INPUT);pinMode(PinA_left,INPUT);// in 0 in 1
  140.    Serial.println("Pin mode ...");
  141.    /////////////////////////////interrupt/////////////////////////////////////////////
  142.    attachInterrupt(0, Code_right, FALLING);attachInterrupt(1, Code_left, FALLING);
  143.    
  144. }

  145. void loop()
  146. {
  147.    if (Serial.available() > 0){val = Serial.read();Serial.println(val);}
  148.      switch(val){
  149.      case 'a':Speed_need=30;Turn_need=0;positions=80;break;//Go
  150.      case 'b':Speed_need=10;Turn_need=-10;positions=10;break;//right
  151.      case 'c':Speed_need=10;Turn_need=10;positions=10;break;//left
  152.      case 'd':Speed_need=0;Turn_need=0;positions=0;break;
  153.      default:Speed_need=0;Turn_need=0;positions=0;break;}//stop
  154.    
  155.      //Speed_need=30;Turn_need=0;positions=80;  
  156.      //SetMotorVoltage(100,100);
  157.    
  158.   
  159.          //Serial.print("count_left");Serial.println(count_left);
  160.     accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz);
  161.     //Serial.print("a/g:\t");
  162.    // Serial.print(ax); Serial.print("\t");
  163.    // Serial.print(ay); Serial.print("\t");
  164.    // Serial.print(az); Serial.print("\t");
  165.    // Serial.print(gx); Serial.print("\t");
  166.     //Serial.print(gy); Serial.print("\t");
  167.    // Serial.println(gz);
  168.    
  169.     Angle_Calcu();
  170.    
  171.     //Serial.print("Angle");Serial.println(Angle);
  172.    
  173.     PWM_Calcu();
  174.   
  175.    //if(millis()-old_time>=500){ Serial.print("count_right");Serial.print(count_right);Serial.print("count_left");Serial.println(count_left);old_time=millis();count_right=0;count_left=0;}     
  176. }
  177. void PWM_Calcu(void)
  178. {
  179.    Serial.println(Angle);
  180.   if (abs(Angle)>40)
  181.     {qd=1;
  182.     SetMotorVoltage(0,0);}//角度大于45度 停止PWM输出
  183.     else
  184.     { //Speed_need=30;Turn_need=0;positions=80;
  185.       //////////////////////
  186.       qd=0;
  187.       speeds=(count_left + count_right)*0.5;
  188.       diff_speeds = count_left - count_right;
  189.       diff_speeds_all += diff_speeds;
  190.       speeds_filter *=0.85;  //一阶互补滤波
  191.       speeds_filter +=speeds*0.15;
  192.       positions += speeds_filter;
  193.       positions += Speed_need;
  194.       positions = constrain(positions, -2300, 2300);//抗积分饱和
  195.       ////////////////////
  196.       Output=Kp*Angle+Kd*Gyro_y+ Ksp*speeds_filter + Ksi*positions ;
  197.       //Serial.println(Output);
  198.       if(Turn_need==0){PWM_right=Output-diff_speeds_all;
  199.       PWM_left=Output+diff_speeds_all;}
  200.       
  201.       PWM_right=Output+Turn_need;
  202.       PWM_left=Output-Turn_need;
  203.       
  204.       if(PWM_right>=0){PWM_right+=PWM_right_least;}else{PWM_right-=PWM_right_least;}
  205.       if(PWM_left>=0){PWM_left+=PWM_left_least;}else{PWM_left-=PWM_left_least;}
  206.       //Serial.print(PWM_left);Serial.print("\t");Serial.println(PWM_right);
  207.       SetMotorVoltage(PWM_left,PWM_right);}
  208.        count_left = 0;
  209.   count_right = 0;
  210. }

复制代码


回复

使用道具 举报

发表于 2018-2-13 10:32:19 | 显示全部楼层
不如来个视频展示下现阶段的成果是怎么样的
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则 需要先绑定手机号

Archiver|联系我们|极客工坊

GMT+8, 2024-3-28 21:59 , Processed in 0.044152 second(s), 18 queries .

Powered by Discuz! X3.4 Licensed

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表