极客工坊

 找回密码
 注册

QQ登录

只需一步,快速开始

查看: 122946|回复: 254

十大滤波算法程序大全(Arduino精编无错版)

    [复制链接]
发表于 2013-11-1 23:45:14 | 显示全部楼层 |阅读模式
本帖最后由 shenhaiyu 于 2013-11-11 23:03 编辑

最近用Arduino做电子秤,为了解决数据的跳变研究了不少滤波算法。网上能找到大把的十大滤波算法帖子,每一篇都不太一样,都号称精编啊,除错啊什么的,可是放到板子里却没一个能正常跑起来的。于是决定自己整理一下这些程序,完美移植到Arduino中。

所以大家看到这个帖子的时候,不要怀疑我重复发帖。我的代码都是经过反复试验,复制到Arduino中就能开跑的成品代码,移植到自己的程序中非常方便。而且都仔细研究了各个算法,把错误都修正了的(别的程序连冒泡算法都是溢出的,不信自己找来细看看),所以也算个小原创吧,在别人基础上的原创。

转载请注明出处:极客工坊  http://www.geek-workshop.com/thread-7694-1-1.html

By shenhaiyu 2013-11-01



1、限幅滤波法(又称程序判断滤波法)
2、中位值滤波法
3、算术平均滤波法
4、递推平均滤波法(又称滑动平均滤波法)
5、中位值平均滤波法(又称防脉冲干扰平均滤波法)
6、限幅平均滤波法
7、一阶滞后滤波法
8、加权递推平均滤波法
9、消抖滤波法
10、限幅消抖滤波法
11、新增加 卡尔曼滤波(非扩展卡尔曼),代码在17楼(点击这里)感谢zhangzhe0617分享

程序默认对int类型数据进行滤波,如需要对其他类型进行滤波,只需要把程序中所有int替换成long、float或者double即可。



1、限幅滤波法(又称程序判断滤波法)
  1. /*
  2. A、名称:限幅滤波法(又称程序判断滤波法)
  3. B、方法:
  4.     根据经验判断,确定两次采样允许的最大偏差值(设为A),
  5.     每次检测到新值时判断:
  6.     如果本次值与上次值之差<=A,则本次值有效,
  7.     如果本次值与上次值之差>A,则本次值无效,放弃本次值,用上次值代替本次值。
  8. C、优点:
  9.     能有效克服因偶然因素引起的脉冲干扰。
  10. D、缺点:
  11.     无法抑制那种周期性的干扰。
  12.     平滑度差。
  13. E、整理:shenhaiyu 2013-11-01
  14. */

  15. int Filter_Value;
  16. int Value;

  17. void setup() {
  18.   Serial.begin(9600);       // 初始化串口通信
  19.   randomSeed(analogRead(0)); // 产生随机种子
  20.   Value = 300;
  21. }

  22. void loop() {
  23.   Filter_Value = Filter();       // 获得滤波器输出值
  24.   Value = Filter_Value;          // 最近一次有效采样的值,该变量为全局变量
  25.   Serial.println(Filter_Value); // 串口输出
  26.   delay(50);
  27. }

  28. // 用于随机产生一个300左右的当前值
  29. int Get_AD() {
  30.   return random(295, 305);
  31. }

  32. // 限幅滤波法(又称程序判断滤波法)
  33. #define FILTER_A 1
  34. int Filter() {
  35.   int NewValue;
  36.   NewValue = Get_AD();
  37.   if(((NewValue - Value) > FILTER_A) || ((Value - NewValue) > FILTER_A))
  38.     return Value;
  39.   else
  40.     return NewValue;
  41. }
复制代码





2、中位值滤波法
  1. /*
  2. A、名称:中位值滤波法
  3. B、方法:
  4.     连续采样N次(N取奇数),把N次采样值按大小排列,
  5.     取中间值为本次有效值。
  6. C、优点:
  7.     能有效克服因偶然因素引起的波动干扰;
  8.     对温度、液位的变化缓慢的被测参数有良好的滤波效果。
  9. D、缺点:
  10.     对流量、速度等快速变化的参数不宜。
  11. E、整理:shenhaiyu 2013-11-01
  12. */

  13. int Filter_Value;

  14. void setup() {
  15.   Serial.begin(9600);       // 初始化串口通信
  16.   randomSeed(analogRead(0)); // 产生随机种子
  17. }

  18. void loop() {
  19.   Filter_Value = Filter();       // 获得滤波器输出值
  20.   Serial.println(Filter_Value); // 串口输出
  21.   delay(50);
  22. }

  23. // 用于随机产生一个300左右的当前值
  24. int Get_AD() {
  25.   return random(295, 305);
  26. }

  27. // 中位值滤波法
  28. #define FILTER_N 101
  29. int Filter() {
  30.   int filter_buf[FILTER_N];
  31.   int i, j;
  32.   int filter_temp;
  33.   for(i = 0; i < FILTER_N; i++) {
  34.     filter_buf[i] = Get_AD();
  35.     delay(1);
  36.   }
  37.   // 采样值从小到大排列(冒泡法)
  38.   for(j = 0; j < FILTER_N - 1; j++) {
  39.     for(i = 0; i < FILTER_N - 1 - j; i++) {
  40.       if(filter_buf[i] > filter_buf[i + 1]) {
  41.         filter_temp = filter_buf[i];
  42.         filter_buf[i] = filter_buf[i + 1];
  43.         filter_buf[i + 1] = filter_temp;
  44.       }
  45.     }
  46.   }
  47.   return filter_buf[(FILTER_N - 1) / 2];
  48. }
复制代码





3、算术平均滤波法
  1. /*
  2. A、名称:算术平均滤波法
  3. B、方法:
  4.     连续取N个采样值进行算术平均运算:
  5.     N值较大时:信号平滑度较高,但灵敏度较低;
  6.     N值较小时:信号平滑度较低,但灵敏度较高;
  7.     N值的选取:一般流量,N=12;压力:N=4。
  8. C、优点:
  9.     适用于对一般具有随机干扰的信号进行滤波;
  10.     这种信号的特点是有一个平均值,信号在某一数值范围附近上下波动。
  11. D、缺点:
  12.     对于测量速度较慢或要求数据计算速度较快的实时控制不适用;
  13.     比较浪费RAM。
  14. E、整理:shenhaiyu 2013-11-01
  15. */

  16. int Filter_Value;

  17. void setup() {
  18.   Serial.begin(9600);       // 初始化串口通信
  19.   randomSeed(analogRead(0)); // 产生随机种子
  20. }

  21. void loop() {
  22.   Filter_Value = Filter();       // 获得滤波器输出值
  23.   Serial.println(Filter_Value); // 串口输出
  24.   delay(50);
  25. }

  26. // 用于随机产生一个300左右的当前值
  27. int Get_AD() {
  28.   return random(295, 305);
  29. }

  30. // 算术平均滤波法
  31. #define FILTER_N 12
  32. int Filter() {
  33.   int i;
  34.   int filter_sum = 0;
  35.   for(i = 0; i < FILTER_N; i++) {
  36.     filter_sum += Get_AD();
  37.     delay(1);
  38.   }
  39.   return (int)(filter_sum / FILTER_N);
  40. }
复制代码





4、递推平均滤波法(又称滑动平均滤波法)
  1. /*
  2. A、名称:递推平均滤波法(又称滑动平均滤波法)
  3. B、方法:
  4.     把连续取得的N个采样值看成一个队列,队列的长度固定为N,
  5.     每次采样到一个新数据放入队尾,并扔掉原来队首的一次数据(先进先出原则),
  6.     把队列中的N个数据进行算术平均运算,获得新的滤波结果。
  7.     N值的选取:流量,N=12;压力,N=4;液面,N=4-12;温度,N=1-4。
  8. C、优点:
  9.     对周期性干扰有良好的抑制作用,平滑度高;
  10.     适用于高频振荡的系统。
  11. D、缺点:
  12.     灵敏度低,对偶然出现的脉冲性干扰的抑制作用较差;
  13.     不易消除由于脉冲干扰所引起的采样值偏差;
  14.     不适用于脉冲干扰比较严重的场合;
  15.     比较浪费RAM。
  16. E、整理:shenhaiyu 2013-11-01
  17. */

  18. int Filter_Value;

  19. void setup() {
  20.   Serial.begin(9600);       // 初始化串口通信
  21.   randomSeed(analogRead(0)); // 产生随机种子
  22. }

  23. void loop() {
  24.   Filter_Value = Filter();       // 获得滤波器输出值
  25.   Serial.println(Filter_Value); // 串口输出
  26.   delay(50);
  27. }

  28. // 用于随机产生一个300左右的当前值
  29. int Get_AD() {
  30.   return random(295, 305);
  31. }

  32. // 递推平均滤波法(又称滑动平均滤波法)
  33. #define FILTER_N 12
  34. int filter_buf[FILTER_N + 1];
  35. int Filter() {
  36.   int i;
  37.   int filter_sum = 0;
  38.   filter_buf[FILTER_N] = Get_AD();
  39.   for(i = 0; i < FILTER_N; i++) {
  40.     filter_buf[i] = filter_buf[i + 1]; // 所有数据左移,低位仍掉
  41.     filter_sum += filter_buf[i];
  42.   }
  43.   return (int)(filter_sum / FILTER_N);
  44. }
复制代码





5、中位值平均滤波法(又称防脉冲干扰平均滤波法)
  1. /*
  2. A、名称:中位值平均滤波法(又称防脉冲干扰平均滤波法)
  3. B、方法:
  4.     采一组队列去掉最大值和最小值后取平均值,
  5.     相当于“中位值滤波法”+“算术平均滤波法”。
  6.     连续采样N个数据,去掉一个最大值和一个最小值,
  7.     然后计算N-2个数据的算术平均值。
  8.     N值的选取:3-14。
  9. C、优点:
  10.     融合了“中位值滤波法”+“算术平均滤波法”两种滤波法的优点。
  11.     对于偶然出现的脉冲性干扰,可消除由其所引起的采样值偏差。
  12.     对周期干扰有良好的抑制作用。
  13.     平滑度高,适于高频振荡的系统。
  14. D、缺点:
  15.     计算速度较慢,和算术平均滤波法一样。
  16.     比较浪费RAM。
  17. E、整理:shenhaiyu 2013-11-01
  18. */

  19. int Filter_Value;

  20. void setup() {
  21.   Serial.begin(9600);       // 初始化串口通信
  22.   randomSeed(analogRead(0)); // 产生随机种子
  23. }

  24. void loop() {
  25.   Filter_Value = Filter();       // 获得滤波器输出值
  26.   Serial.println(Filter_Value); // 串口输出
  27.   delay(50);
  28. }

  29. // 用于随机产生一个300左右的当前值
  30. int Get_AD() {
  31.   return random(295, 305);
  32. }

  33. // 中位值平均滤波法(又称防脉冲干扰平均滤波法)(算法1)
  34. #define FILTER_N 100
  35. int Filter() {
  36.   int i, j;
  37.   int filter_temp, filter_sum = 0;
  38.   int filter_buf[FILTER_N];
  39.   for(i = 0; i < FILTER_N; i++) {
  40.     filter_buf[i] = Get_AD();
  41.     delay(1);
  42.   }
  43.   // 采样值从小到大排列(冒泡法)
  44.   for(j = 0; j < FILTER_N - 1; j++) {
  45.     for(i = 0; i < FILTER_N - 1 - j; i++) {
  46.       if(filter_buf[i] > filter_buf[i + 1]) {
  47.         filter_temp = filter_buf[i];
  48.         filter_buf[i] = filter_buf[i + 1];
  49.         filter_buf[i + 1] = filter_temp;
  50.       }
  51.     }
  52.   }
  53.   // 去除最大最小极值后求平均
  54.   for(i = 1; i < FILTER_N - 1; i++) filter_sum += filter_buf[i];
  55.   return filter_sum / (FILTER_N - 2);
  56. }


  57. //  中位值平均滤波法(又称防脉冲干扰平均滤波法)(算法2)
  58. /*
  59. #define FILTER_N 100
  60. int Filter() {
  61.   int i;
  62.   int filter_sum = 0;
  63.   int filter_max, filter_min;
  64.   int filter_buf[FILTER_N];
  65.   for(i = 0; i < FILTER_N; i++) {
  66.     filter_buf[i] = Get_AD();
  67.     delay(1);
  68.   }
  69.   filter_max = filter_buf[0];
  70.   filter_min = filter_buf[0];
  71.   filter_sum = filter_buf[0];
  72.   for(i = FILTER_N - 1; i > 0; i--) {
  73.     if(filter_buf[i] > filter_max)
  74.       filter_max=filter_buf[i];
  75.     else if(filter_buf[i] < filter_min)
  76.       filter_min=filter_buf[i];
  77.     filter_sum = filter_sum + filter_buf[i];
  78.     filter_buf[i] = filter_buf[i - 1];
  79.   }
  80.   i = FILTER_N - 2;
  81.   filter_sum = filter_sum - filter_max - filter_min + i / 2; // +i/2 的目的是为了四舍五入
  82.   filter_sum = filter_sum / i;
  83.   return filter_sum;
  84. }*/
复制代码





6、限幅平均滤波法
  1. /*
  2. A、名称:限幅平均滤波法
  3. B、方法:
  4.     相当于“限幅滤波法”+“递推平均滤波法”;
  5.     每次采样到的新数据先进行限幅处理,
  6.     再送入队列进行递推平均滤波处理。
  7. C、优点:
  8.     融合了两种滤波法的优点;
  9.     对于偶然出现的脉冲性干扰,可消除由于脉冲干扰所引起的采样值偏差。
  10. D、缺点:
  11.     比较浪费RAM。
  12. E、整理:shenhaiyu 2013-11-01
  13. */

  14. #define FILTER_N 12
  15. int Filter_Value;
  16. int filter_buf[FILTER_N];

  17. void setup() {
  18.   Serial.begin(9600);       // 初始化串口通信
  19.   randomSeed(analogRead(0)); // 产生随机种子
  20.   filter_buf[FILTER_N - 2] = 300;
  21. }

  22. void loop() {
  23.   Filter_Value = Filter();       // 获得滤波器输出值
  24.   Serial.println(Filter_Value); // 串口输出
  25.   delay(50);
  26. }

  27. // 用于随机产生一个300左右的当前值
  28. int Get_AD() {
  29.   return random(295, 305);
  30. }

  31. // 限幅平均滤波法
  32. #define FILTER_A 1
  33. int Filter() {
  34.   int i;
  35.   int filter_sum = 0;
  36.   filter_buf[FILTER_N - 1] = Get_AD();
  37.   if(((filter_buf[FILTER_N - 1] - filter_buf[FILTER_N - 2]) > FILTER_A) || ((filter_buf[FILTER_N - 2] - filter_buf[FILTER_N - 1]) > FILTER_A))
  38.     filter_buf[FILTER_N - 1] = filter_buf[FILTER_N - 2];
  39.   for(i = 0; i < FILTER_N - 1; i++) {
  40.     filter_buf[i] = filter_buf[i + 1];
  41.     filter_sum += filter_buf[i];
  42.   }
  43.   return (int)filter_sum / (FILTER_N - 1);
  44. }
复制代码





7、一阶滞后滤波法
  1. /*
  2. A、名称:一阶滞后滤波法
  3. B、方法:
  4.     取a=0-1,本次滤波结果=(1-a)*本次采样值+a*上次滤波结果。
  5. C、优点:
  6.     对周期性干扰具有良好的抑制作用;
  7.     适用于波动频率较高的场合。
  8. D、缺点:
  9.     相位滞后,灵敏度低;
  10.     滞后程度取决于a值大小;
  11.     不能消除滤波频率高于采样频率1/2的干扰信号。
  12. E、整理:shenhaiyu 2013-11-01
  13. */

  14. int Filter_Value;
  15. int Value;

  16. void setup() {
  17.   Serial.begin(9600);       // 初始化串口通信
  18.   randomSeed(analogRead(0)); // 产生随机种子
  19.   Value = 300;
  20. }

  21. void loop() {
  22.   Filter_Value = Filter();       // 获得滤波器输出值
  23.   Serial.println(Filter_Value); // 串口输出
  24.   delay(50);
  25. }

  26. // 用于随机产生一个300左右的当前值
  27. int Get_AD() {
  28.   return random(295, 305);
  29. }

  30. // 一阶滞后滤波法
  31. #define FILTER_A 0.01
  32. int Filter() {
  33.   int NewValue;
  34.   NewValue = Get_AD();
  35.   Value = (int)((float)NewValue * FILTER_A + (1.0 - FILTER_A) * (float)Value);
  36.   return Value;
  37. }
复制代码





8、加权递推平均滤波法
  1. /*
  2. A、名称:加权递推平均滤波法
  3. B、方法:
  4.     是对递推平均滤波法的改进,即不同时刻的数据加以不同的权;
  5.     通常是,越接近现时刻的数据,权取得越大。
  6.     给予新采样值的权系数越大,则灵敏度越高,但信号平滑度越低。
  7. C、优点:
  8.     适用于有较大纯滞后时间常数的对象,和采样周期较短的系统。
  9. D、缺点:
  10.     对于纯滞后时间常数较小、采样周期较长、变化缓慢的信号;
  11.     不能迅速反应系统当前所受干扰的严重程度,滤波效果差。
  12. E、整理:shenhaiyu 2013-11-01
  13. */

  14. int Filter_Value;

  15. void setup() {
  16.   Serial.begin(9600);       // 初始化串口通信
  17.   randomSeed(analogRead(0)); // 产生随机种子
  18. }

  19. void loop() {
  20.   Filter_Value = Filter();       // 获得滤波器输出值
  21.   Serial.println(Filter_Value); // 串口输出
  22.   delay(50);
  23. }

  24. // 用于随机产生一个300左右的当前值
  25. int Get_AD() {
  26.   return random(295, 305);
  27. }

  28. // 加权递推平均滤波法
  29. #define FILTER_N 12
  30. int coe[FILTER_N] = {1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12};    // 加权系数表
  31. int sum_coe = 1 + 2 + 3 + 4 + 5 + 6 + 7 + 8 + 9 + 10 + 11 + 12; // 加权系数和
  32. int filter_buf[FILTER_N + 1];
  33. int Filter() {
  34.   int i;
  35.   int filter_sum = 0;
  36.   filter_buf[FILTER_N] = Get_AD();
  37.   for(i = 0; i < FILTER_N; i++) {
  38.     filter_buf[i] = filter_buf[i + 1]; // 所有数据左移,低位仍掉
  39.     filter_sum += filter_buf[i] * coe[i];
  40.   }
  41.   filter_sum /= sum_coe;
  42.   return filter_sum;
  43. }
复制代码





9、消抖滤波法
  1. /*
  2. A、名称:消抖滤波法
  3. B、方法:
  4.     设置一个滤波计数器,将每次采样值与当前有效值比较:
  5.     如果采样值=当前有效值,则计数器清零;
  6.     如果采样值<>当前有效值,则计数器+1,并判断计数器是否>=上限N(溢出);
  7.     如果计数器溢出,则将本次值替换当前有效值,并清计数器。
  8. C、优点:
  9.     对于变化缓慢的被测参数有较好的滤波效果;
  10.     可避免在临界值附近控制器的反复开/关跳动或显示器上数值抖动。
  11. D、缺点:
  12.     对于快速变化的参数不宜;
  13.     如果在计数器溢出的那一次采样到的值恰好是干扰值,则会将干扰值当作有效值导入系统。
  14. E、整理:shenhaiyu 2013-11-01
  15. */

  16. int Filter_Value;
  17. int Value;

  18. void setup() {
  19.   Serial.begin(9600);       // 初始化串口通信
  20.   randomSeed(analogRead(0)); // 产生随机种子
  21.   Value = 300;
  22. }

  23. void loop() {
  24.   Filter_Value = Filter();       // 获得滤波器输出值
  25.   Serial.println(Filter_Value); // 串口输出
  26.   delay(50);
  27. }

  28. // 用于随机产生一个300左右的当前值
  29. int Get_AD() {
  30.   return random(295, 305);
  31. }

  32. // 消抖滤波法
  33. #define FILTER_N 12
  34. int i = 0;
  35. int Filter() {
  36.   int new_value;
  37.   new_value = Get_AD();
  38.   if(Value != new_value) {
  39.     i++;
  40.     if(i > FILTER_N) {
  41.       i = 0;
  42.       Value = new_value;
  43.     }
  44.   }
  45.   else
  46.     i = 0;
  47.   return Value;
  48. }
复制代码





10、限幅消抖滤波法
  1. /*
  2. A、名称:限幅消抖滤波法
  3. B、方法:
  4.     相当于“限幅滤波法”+“消抖滤波法”;
  5.     先限幅,后消抖。
  6. C、优点:
  7.     继承了“限幅”和“消抖”的优点;
  8.     改进了“消抖滤波法”中的某些缺陷,避免将干扰值导入系统。
  9. D、缺点:
  10.     对于快速变化的参数不宜。
  11. E、整理:shenhaiyu 2013-11-01
  12. */

  13. int Filter_Value;
  14. int Value;

  15. void setup() {
  16.   Serial.begin(9600);       // 初始化串口通信
  17.   randomSeed(analogRead(0)); // 产生随机种子
  18.   Value = 300;
  19. }

  20. void loop() {
  21.   Filter_Value = Filter();       // 获得滤波器输出值
  22.   Serial.println(Filter_Value); // 串口输出
  23.   delay(50);
  24. }

  25. // 用于随机产生一个300左右的当前值
  26. int Get_AD() {
  27.   return random(295, 305);
  28. }

  29. // 限幅消抖滤波法
  30. #define FILTER_A 1
  31. #define FILTER_N 5
  32. int i = 0;
  33. int Filter() {
  34.   int NewValue;
  35.   int new_value;
  36.   NewValue = Get_AD();
  37.   if(((NewValue - Value) > FILTER_A) || ((Value - NewValue) > FILTER_A))
  38.     new_value = Value;
  39.   else
  40.     new_value = NewValue;
  41.   if(Value != new_value) {
  42.     i++;
  43.     if(i > FILTER_N) {
  44.       i = 0;
  45.       Value = new_value;
  46.     }
  47.   }
  48.   else
  49.     i = 0;
  50.   return Value;
  51. }
复制代码

评分

参与人数 1威望 +1 收起 理由
幻生幻灭 + 1 赞一个!

查看全部评分

回复

使用道具 举报

发表于 2013-11-2 19:18:02 | 显示全部楼层
建议编辑一下这个帖子作为滤波专用的,这样大家查起来也方便。下面是卡尔曼滤波,不是扩展的,但是输出平稳的俯仰和滚转应该够了(凑乎用吧我也不是专业写代码的,欢迎大家拍)
  1. #include <Wire.h> // I2C library, gyroscope

  2. // Accelerometer ADXL345
  3. #define ACC (0x53)    //ADXL345 ACC address
  4. #define A_TO_READ (6)        //num of bytes we are going to read each time (two bytes for each axis)


  5. // Gyroscope ITG3200
  6. #define GYRO 0x68 // gyro address, binary = 11101000 when AD0 is connected to Vcc (see schematics of your breakout board)
  7. #define G_SMPLRT_DIV 0x15   
  8. #define G_DLPF_FS 0x16   
  9. #define G_INT_CFG 0x17
  10. #define G_PWR_MGM 0x3E

  11. #define G_TO_READ 8 // 2 bytes for each axis x, y, z


  12. // offsets are chip specific.
  13. int a_offx = 0;
  14. int a_offy = 0;
  15. int a_offz = 0;

  16. int g_offx = 0;
  17. int g_offy = 0;
  18. int g_offz = 0;
  19. ////////////////////////

  20. ////////////////////////
  21. char str[512];

  22. void initAcc() {
  23.   //Turning on the ADXL345
  24.   writeTo(ACC, 0x2D, 0);      
  25.   writeTo(ACC, 0x2D, 16);
  26.   writeTo(ACC, 0x2D, 8);
  27.   //by default the device is in +-2g range reading
  28. }

  29. void getAccelerometerData(int* result) {
  30.   int regAddress = 0x32;    //first axis-acceleration-data register on the ADXL345
  31.   byte buff[A_TO_READ];
  32.   
  33.   readFrom(ACC, regAddress, A_TO_READ, buff); //read the acceleration data from the ADXL345
  34.   
  35.   //each axis reading comes in 10 bit resolution, ie 2 bytes.  Least Significat Byte first!!
  36.   //thus we are converting both bytes in to one int
  37.   result[0] = (((int)buff[1]) << 8) | buff[0] + a_offx;   
  38.   result[1] = (((int)buff[3]) << 8) | buff[2] + a_offy;
  39.   result[2] = (((int)buff[5]) << 8) | buff[4] + a_offz;
  40. }

  41. //initializes the gyroscope
  42. void initGyro()
  43. {
  44.   /*****************************************
  45.   * ITG 3200
  46.   * power management set to:
  47.   * clock select = internal oscillator
  48.   *     no reset, no sleep mode
  49.   *   no standby mode
  50.   * sample rate to = 125Hz
  51.   * parameter to +/- 2000 degrees/sec
  52.   * low pass filter = 5Hz
  53.   * no interrupt
  54.   ******************************************/
  55.   writeTo(GYRO, G_PWR_MGM, 0x00);
  56.   writeTo(GYRO, G_SMPLRT_DIV, 0x07); // EB, 50, 80, 7F, DE, 23, 20, FF
  57.   writeTo(GYRO, G_DLPF_FS, 0x1E); // +/- 2000 dgrs/sec, 1KHz, 1E, 19
  58.   writeTo(GYRO, G_INT_CFG, 0x00);
  59. }


  60. void getGyroscopeData(int * result)
  61. {
  62.   /**************************************
  63.   Gyro ITG-3200 I2C
  64.   registers:
  65.   temp MSB = 1B, temp LSB = 1C
  66.   x axis MSB = 1D, x axis LSB = 1E
  67.   y axis MSB = 1F, y axis LSB = 20
  68.   z axis MSB = 21, z axis LSB = 22
  69.   *************************************/

  70.   int regAddress = 0x1B;
  71.   int temp, x, y, z;
  72.   byte buff[G_TO_READ];
  73.   
  74.   readFrom(GYRO, regAddress, G_TO_READ, buff); //read the gyro data from the ITG3200
  75.   
  76.   result[0] = ((buff[2] << 8) | buff[3]) + g_offx;
  77.   result[1] = ((buff[4] << 8) | buff[5]) + g_offy;
  78.   result[2] = ((buff[6] << 8) | buff[7]) + g_offz;
  79.   result[3] = (buff[0] << 8) | buff[1]; // temperature
  80.   
  81. }


  82. float xz=0,yx=0,yz=0;
  83. float p_xz=1,p_yx=1,p_yz=1;
  84. float q_xz=0.0025,q_yx=0.0025,q_yz=0.0025;
  85. float k_xz=0,k_yx=0,k_yz=0;
  86. float r_xz=0.25,r_yx=0.25,r_yz=0.25;
  87.   //int acc_temp[3];
  88.   //float acc[3];
  89.   int acc[3];
  90.   int gyro[4];
  91.   float Axz;
  92.   float Ayx;
  93.   float Ayz;
  94.   float t=0.025;
  95. void setup()
  96. {
  97.   Serial.begin(9600);
  98.   Wire.begin();
  99.   initAcc();
  100.   initGyro();
  101.   
  102. }

  103. //unsigned long timer = 0;
  104. //float o;
  105. void loop()
  106. {
  107.   
  108.   getAccelerometerData(acc);
  109.   getGyroscopeData(gyro);
  110.   //timer = millis();
  111.   sprintf(str, "%d,%d,%d,%d,%d,%d", acc[0],acc[1],acc[2],gyro[0],gyro[1],gyro[2]);
  112.   
  113.   //acc[0]=acc[0];
  114.   //acc[2]=acc[2];
  115.   //acc[1]=acc[1];
  116.   //r=sqrt(acc[0]*acc[0]+acc[1]*acc[1]+acc[2]*acc[2]);
  117.   gyro[0]=gyro[0]/ 14.375;
  118.   gyro[1]=gyro[1]/ (-14.375);
  119.   gyro[2]=gyro[2]/ 14.375;
  120.   
  121.    
  122.   Axz=(atan2(acc[0],acc[2]))*180/PI;
  123.   Ayx=(atan2(acc[0],acc[1]))*180/PI;
  124.   /*if((acc[0]!=0)&&(acc[1]!=0))
  125.     {
  126.       Ayx=(atan2(acc[0],acc[1]))*180/PI;
  127.     }
  128.     else
  129.     {
  130.       Ayx=t*gyro[2];
  131.     }*/
  132.   Ayz=(atan2(acc[1],acc[2]))*180/PI;
  133.   
  134.   
  135. //kalman filter
  136.   calculate_xz();
  137.   calculate_yx();
  138.   calculate_yz();
  139.   
  140.   //sprintf(str, "%d,%d,%d", xz_1, xy_1, x_1);
  141.   //Serial.print(xz);Serial.print(",");
  142.   //Serial.print(yx);Serial.print(",");
  143.   //Serial.print(yz);Serial.print(",");
  144.   //sprintf(str, "%d,%d,%d,%d,%d,%d", acc[0],acc[1],acc[2],gyro[0],gyro[1],gyro[2]);
  145.   //sprintf(str, "%d,%d,%d",gyro[0],gyro[1],gyro[2]);
  146.     Serial.print(Axz);Serial.print(",");
  147.     //Serial.print(Ayx);Serial.print(",");
  148.     //Serial.print(Ayz);Serial.print(",");
  149.   //Serial.print(str);
  150.   //o=gyro[2];//w=acc[2];
  151.   //Serial.print(o);Serial.print(",");
  152.   //Serial.print(w);Serial.print(",");
  153.   Serial.print("\n");

  154.   
  155.   //delay(50);
  156. }
  157. void calculate_xz()
  158. {

  159. xz=xz+t*gyro[1];
  160. p_xz=p_xz+q_xz;
  161. k_xz=p_xz/(p_xz+r_xz);
  162. xz=xz+k_xz*(Axz-xz);
  163. p_xz=(1-k_xz)*p_xz;
  164. }
  165. void calculate_yx()
  166. {
  167.   
  168.   yx=yx+t*gyro[2];
  169.   p_yx=p_yx+q_yx;
  170.   k_yx=p_yx/(p_yx+r_yx);
  171.   yx=yx+k_yx*(Ayx-yx);
  172.   p_yx=(1-k_yx)*p_yx;

  173. }
  174. void calculate_yz()
  175. {
  176.   yz=yz+t*gyro[0];
  177.   p_yz=p_yz+q_yz;
  178.   k_yz=p_yz/(p_yz+r_yz);
  179.   yz=yz+k_yz*(Ayz-yz);
  180.   p_yz=(1-k_yz)*p_yz;

  181. }


  182. //---------------- Functions
  183. //Writes val to address register on ACC
  184. void writeTo(int DEVICE, byte address, byte val) {
  185.    Wire.beginTransmission(DEVICE); //start transmission to ACC
  186.    Wire.write(address);        // send register address
  187.    Wire.write(val);        // send value to write
  188.    Wire.endTransmission(); //end transmission
  189. }


  190. //reads num bytes starting from address register on ACC in to buff array
  191. void readFrom(int DEVICE, byte address, int num, byte buff[]) {
  192.   Wire.beginTransmission(DEVICE); //start transmission to ACC
  193.   Wire.write(address);        //sends address to read from
  194.   Wire.endTransmission(); //end transmission
  195.   
  196.   Wire.beginTransmission(DEVICE); //start transmission to ACC
  197.   Wire.requestFrom(DEVICE, num);    // request 6 bytes from ACC
  198.   
  199.   int i = 0;
  200.   while(Wire.available())    //ACC may send less than requested (abnormal)
  201.   {
  202.     buff[i] = Wire.read(); // receive a byte
  203.     i++;
  204.   }
  205.   Wire.endTransmission(); //end transmission
  206. }
复制代码

点评

我很想知道,float p_xz=1,p_yx=1,p_yz=1;float q_xz=0.0025,q_yx=0.0025,q_yz=0.0025!这些变量的取值依据?(或者说,为什么这么取值?),希望得到指教......  发表于 2014-4-1 17:15
思路是对的。有2点硬伤:1.只采用加速计和陀螺仪,因此偏航角就不会准确了;2.在预测角度时,用的是欧拉角微分方程简化形式:yaw=0&&pitch=0||roll=0)预测的角度也不准确,最好用四元数微分方程解姿态角。  发表于 2014-3-26 14:39
这段代码似乎没有程序上的滤波,好像是从那个带有硬件滤波的陀螺仪上搬过来的。  发表于 2014-3-25 02:41
要是多写点注释和用法就完美了  发表于 2013-11-4 11:33
感谢分享代码!  发表于 2013-11-4 11:32
回复 支持 1 反对 0

使用道具 举报

发表于 2013-11-2 00:25:37 | 显示全部楼层
算法见过,整理好的还没见过,非常有用!{:soso_e182:}
回复 支持 反对

使用道具 举报

 楼主| 发表于 2013-11-2 00:29:18 | 显示全部楼层
Ansifa 发表于 2013-11-2 00:25
算法见过,整理好的还没见过,非常有用!

是啊,满网都是算法和C++例程,仔细一看都错误连篇,也没有一个能完美的在Arduino上运行,一怒之下全整理出来了。单弄其中一两个算法还算简单,这十个程序整整弄了一天,弄得头昏眼花的,希望没有错误吧~~
回复 支持 反对

使用道具 举报

发表于 2013-11-2 07:41:15 | 显示全部楼层
这个好。。。。严重加精
回复 支持 反对

使用道具 举报

发表于 2013-11-2 08:26:44 | 显示全部楼层
厉害,其实建议一下能不能有个机制能过滤一下不能用的代码。需要卡尔曼(测试过了)的话我再贴上来,四轴上用的
回复 支持 反对

使用道具 举报

 楼主| 发表于 2013-11-2 09:15:22 | 显示全部楼层
弘毅 发表于 2013-11-2 07:41
这个好。。。。严重加精

哈哈,弘大,我建议组织一次算法大赛,然后把代码都整理成库的形式,出一个极客工坊版的算法库
回复 支持 反对

使用道具 举报

 楼主| 发表于 2013-11-2 09:16:05 | 显示全部楼层
zhangzhe0617 发表于 2013-11-2 08:26
厉害,其实建议一下能不能有个机制能过滤一下不能用的代码。需要卡尔曼(测试过了)的话我再贴上来,四轴上 ...

有代码就共享出来呗~~
回复 支持 反对

使用道具 举报

发表于 2013-11-2 09:17:45 | 显示全部楼层
嗯,太好了。多谢分享。。。严重支持

点评

谢谢支持,有好代码也共享出来吧  发表于 2013-11-4 11:25
回复 支持 反对

使用道具 举报

发表于 2013-11-2 10:27:03 | 显示全部楼层
这个相当有用,超声波测距,各种测样都用得到。收了,感谢楼主的辛苦劳动,顶起!

点评

谢谢支持,各种需要滤波的场合都能用,关键是复制下来简单改改就能测试了  发表于 2013-11-4 11:25
回复 支持 反对

使用道具 举报

发表于 2013-11-2 11:06:09 | 显示全部楼层
绝对的好帖子哦~
有一个疑问呢,是不是把传感器输出数值的变量= Filter()?

点评

对的,然后把传感器的数据获取函数换到程序里的Get_AD();  发表于 2013-11-4 11:27
回复 支持 反对

使用道具 举报

高级模式  
您需要登录后才可以回帖 登录 | 注册

本版积分规则

Archiver|联系我们|极客工坊 ( 浙ICP备09023225号 )

GMT+8, 2017-11-23 11:55 , Processed in 0.043885 second(s), 7 queries , File On.

Powered by Discuz! X3.4 Licensed

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表