极客工坊

 找回密码
 注册

QQ登录

只需一步,快速开始

查看: 59778|回复: 26

LaunchPad Energia学习笔记03--用BMP085显示气压与温度

[复制链接]
发表于 2012-9-18 22:20:28 | 显示全部楼层 |阅读模式

首先看一下硬件连接图:
P1.6引脚接SCL,P1.7接SDA,VCC与GND接入模块上对应的就OK




注意~~~因为P1.6也同时连接着LED2,为了不影响IIC的通信,一定要把LED2的跳线帽拔掉,否则就会工作不正常。



我们把下面的代码放入Energia中进行编译,下载进入Launchpad。

  1. /*
  2.   从BMP085传感器读取温度与气压数据。
  3.   通过Serial.print命令以9600波特率发送至串口监视器。
  4. */

  5. #include <Wire.h>
  6. #define BMP085_ADDRESS 0x77  // BMP085的I2C地址
  7. const unsigned char OSS = 0;  // 采样设置

  8. // 校准值
  9. int ac1;
  10. int ac2;
  11. int ac3;
  12. unsigned int ac4;
  13. unsigned int ac5;
  14. unsigned int ac6;
  15. int b1;
  16. int b2;
  17. int mb;
  18. int mc;
  19. int md;

  20. // b5用于计算bmp085GetTemperature(...),它也同时用于bmp085GetPressure(...)
  21. // 所以Temperature(...)必须在Pressure(...)之前声明

  22. long b5;
  23. short temperature;
  24. long pressure;

  25. void setup()
  26. {
  27.   Serial.begin(9600);
  28.   Wire.begin();
  29.   bmp085Calibration();
  30. }

  31. void loop()
  32. {
  33.   temperature = bmp085GetTemperature(bmp085ReadUT());
  34.   pressure = bmp085GetPressure(bmp085ReadUP());
  35.   Serial.print("Temperature: ");
  36.   Serial.print(temperature, DEC);
  37.   Serial.println(" *0.1 deg C");
  38.   Serial.print("Pressure: ");
  39.   Serial.print(pressure, DEC);
  40.   Serial.println(" Pa");
  41.   Serial.println();
  42.   delay(1000);
  43. }

  44. // 存储所有的BMP085的校准值到全局变量
  45. // 校准值用来计算温度与气压
  46. // 这个函数应该放在程序的开头

  47. void bmp085Calibration()
  48. {
  49.   ac1 = bmp085ReadInt(0xAA);
  50.   ac2 = bmp085ReadInt(0xAC);
  51.   ac3 = bmp085ReadInt(0xAE);
  52.   ac4 = bmp085ReadInt(0xB0);
  53.   ac5 = bmp085ReadInt(0xB2);
  54.   ac6 = bmp085ReadInt(0xB4);
  55.   b1 = bmp085ReadInt(0xB6);
  56.   b2 = bmp085ReadInt(0xB8);
  57.   mb = bmp085ReadInt(0xBA);
  58.   mc = bmp085ReadInt(0xBC);
  59.   md = bmp085ReadInt(0xBE);
  60. }

  61. // 计算温度赋值给变量ut
  62. // 返回值的精度在0.1摄氏度

  63. short bmp085GetTemperature(unsigned int ut)
  64. {
  65.   long x1, x2;
  66.   x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  67.   x2 = ((long)mc << 11)/(x1 + md);
  68.   b5 = x1 + x2;
  69.   return ((b5 + 8)>>4);  
  70. }

  71. // 计算压力
  72. // 校准值必须是已知的
  73. // B5在bmp085GetTemperature(...)需要使用,所以必须先调用。
  74. // 返回值以Pa为单位

  75. long bmp085GetPressure(unsigned long up)

  76. {
  77.   long x1, x2, x3, b3, b6, p;
  78.   unsigned long b4, b7;
  79.   b6 = b5 - 4000;
  80.   // 计算B3
  81.   x1 = (b2 * (b6 * b6)>>12)>>11;
  82.   x2 = (ac2 * b6)>>11;
  83.   x3 = x1 + x2;
  84.   b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
  85.   // 计算B4
  86.   x1 = (ac3 * b6)>>13;
  87.   x2 = (b1 * ((b6 * b6)>>12))>>16;
  88.   x3 = ((x1 + x2) + 2)>>2;
  89.   b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
  90.   b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  91.   if (b7 < 0x80000000)
  92.     p = (b7<<1)/b4;
  93.   else
  94.     p = (b7/b4)<<1;
  95.   x1 = (p>>8) * (p>>8);
  96.   x1 = (x1 * 3038)>>16;
  97.   x2 = (-7357 * p)>>16;
  98.   p += (x1 + x2 + 3791)>>4;
  99.   return p;
  100. }

  101. // 在BMP085的'address'中读取一个字节
  102. char bmp085Read(unsigned char address)
  103. {
  104.   unsigned char data;
  105.   Wire.beginTransmission(BMP085_ADDRESS);
  106.   Wire.write(address);
  107.   Wire.endTransmission();
  108.   Wire.requestFrom(BMP085_ADDRESS, 1);
  109.   while(!Wire.available())  ;
  110.   return Wire.read();
  111. }
  112. // 从BMP085读取两个字节
  113. // 第一个字节是从'address'
  114. // 第二个字节是从'address'+1
  115. int bmp085ReadInt(unsigned char address)
  116. {
  117.   unsigned char msb, lsb;
  118.   Wire.beginTransmission(BMP085_ADDRESS);
  119.   Wire.write(address);
  120.   Wire.endTransmission();
  121.   Wire.requestFrom(BMP085_ADDRESS, 2);
  122.   while(Wire.available()<2);
  123.   msb = Wire.read();
  124.   lsb = Wire.read();
  125.   return (int) msb<<8 | lsb;
  126. }

  127. // 读取未补偿的温度值
  128. unsigned int bmp085ReadUT()

  129. {
  130.   unsigned int ut;
  131.   // 在寄存器0xF4写入0x2E
  132.   // 这个用来请求进行温度读取
  133.   Wire.beginTransmission(BMP085_ADDRESS);
  134.   
  135.   Wire.write(0xF4);
  136.   
  137.   Wire.write(0x2E);
  138.   Wire.endTransmission();
  139.   // 至少等待4.5ms
  140.   delay(5);
  141.   // 从寄存器0xF6与0xF7读取两个字节
  142.   ut = bmp085ReadInt(0xF6);
  143.   return ut;
  144. }

  145. // 读取未补偿的压力值
  146. unsigned long bmp085ReadUP()
  147. {
  148.   unsigned char msb, lsb, xlsb;
  149.   unsigned long up = 0;
  150.   // 写入0x34+(OSS<<6)到寄存器0xF4
  151.   // 请求气压数据读取
  152.   Wire.beginTransmission(BMP085_ADDRESS);
  153.   Wire.write(0xF4);
  154.   Wire.write(0x34 + (OSS<<6));
  155.   Wire.endTransmission();
  156.   // 等待转换,延迟时间依赖于OSS
  157.   delay(2 + (3<<OSS));
  158.   // 读取寄存器0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  159.   Wire.beginTransmission(BMP085_ADDRESS);
  160.   Wire.write(0xF6);
  161.   Wire.endTransmission();
  162.   Wire.requestFrom(BMP085_ADDRESS, 3);
  163.   // 等待数据变为可用
  164.   while(Wire.available() < 3);
  165.   msb = Wire.read();
  166.   lsb = Wire.read();
  167.   xlsb = Wire.read();
  168.   up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
  169.   return up;
  170. }
复制代码


下载程序的模式,TX RX的跳线帽一定要纵向链接。如图:



当下载好以后,我们需要把两个跳线帽拔下来,横向连接,这样子才能把数据通过串口发回电脑上,如图:



然后启动Energia的串口监视器,我们就能看到BMP085气压传感器返回的数据了。

本帖子中包含更多资源

您需要 登录 才可以下载或查看,没有帐号?注册

x
回复

使用道具 举报

发表于 2012-9-18 22:54:38 | 显示全部楼层
这个和arduino的库一样的吧?
回复 支持 反对

使用道具 举报

 楼主| 发表于 2012-9-18 22:58:57 | 显示全部楼层
Randy 发表于 2012-9-18 22:54
这个和arduino的库一样的吧?

嗯。。。。一样。。代码都通用。。。
回复 支持 反对

使用道具 举报

发表于 2012-9-19 09:56:22 | 显示全部楼层
fritzing 中的两处跳帽未处理,容易误导新手的说哦
回复 支持 反对

使用道具 举报

发表于 2012-9-19 11:03:31 | 显示全部楼层
教程写得不错 哈哈
回复 支持 反对

使用道具 举报

发表于 2012-9-19 16:55:38 | 显示全部楼层
我串口通信的时候  跳线帽是不需要改动的啊

弘毅  你的  launchpad 是什么版本的??

我的盒子上 rev 是 0033317
回复 支持 反对

使用道具 举报

 楼主| 发表于 2012-9-19 17:17:54 | 显示全部楼层
┏ωǒ┛菰独 发表于 2012-9-19 16:55
我串口通信的时候  跳线帽是不需要改动的啊

弘毅  你的  launchpad 是什么版本的??


我的板子上是REV.1.5~~~盒子上。。得明天去翻翻
回复 支持 反对

使用道具 举报

发表于 2012-9-19 17:32:25 | 显示全部楼层
弘毅 发表于 2012-9-19 17:17
我的板子上是REV.1.5~~~盒子上。。得明天去翻翻

我的也是rev1.5  不用翻了...好奇怪..不改跳线帽确实用不起来吗?
还有 ,我用iar烧程序的时候不需要txd和rxd,我这两个跳线帽通常也是移除掉的,因为串口电平会干扰.
430用在arduino下是不是用了bootloader?
回复 支持 反对

使用道具 举报

 楼主| 发表于 2012-9-19 17:57:18 | 显示全部楼层
┏ωǒ┛菰独 发表于 2012-9-19 17:32
我的也是rev1.5  不用翻了...好奇怪..不改跳线帽确实用不起来吗?
还有 ,我用iar烧程序的时候不需要txd ...

没用bootloader~~~用Energia往串口监视器发送数据。。就需要改跳线帽,很麻烦。。。不知道怎么能。。不改跳线帽就能用。
回复 支持 反对

使用道具 举报

发表于 2012-9-20 16:38:42 | 显示全部楼层
=.= 我一直横向就可以啊。
回复 支持 反对

使用道具 举报

 楼主| 发表于 2012-9-20 17:15:42 | 显示全部楼层
水乐天 发表于 2012-9-20 16:38
=.= 我一直横向就可以啊。

啊。。。。横向也能下载程序。我还没试。。。赶紧试试
回复 支持 反对

使用道具 举报

发表于 2012-9-21 11:04:04 | 显示全部楼层
┏ωǒ┛菰独 发表于 2012-9-19 17:32
我的也是rev1.5  不用翻了...好奇怪..不改跳线帽确实用不起来吗?
还有 ,我用iar烧程序的时候不需要txd ...

根据TI说明横向连接表示使用硬件串口通信,就是G2553上的硬件串口,如果纵向连接就是使用软件模拟的方式实现串口通信的。
回复 支持 反对

使用道具 举报

发表于 2012-9-21 12:25:21 | 显示全部楼层
AndersonBY 发表于 2012-9-21 11:04
根据TI说明横向连接表示使用硬件串口通信,就是G2553上的硬件串口,如果纵向连接就是使用软件模拟的方式实 ...

你这句话突然点明白了 为什么我前些日子把launchpad用作usb转ttl,给msp430f5438板子用的时候,为什么电平有问题...原来我忽略了它电路设计的一个部分.
回复 支持 反对

使用道具 举报

发表于 2013-2-22 09:49:19 | 显示全部楼层
谢谢,学习了。问个问题:如果另外再连一个I2C设备,如MPU6050,它也要用到SDA和SCL,它们会发生冲突吗?软件上如何处理?
回复 支持 反对

使用道具 举报

 楼主| 发表于 2013-2-22 09:50:42 | 显示全部楼层
zintiger 发表于 2013-2-22 09:49
谢谢,学习了。问个问题:如果另外再连一个I2C设备,如MPU6050,它也要用到SDA和SCL,它们会发生冲突吗?软 ...

只要I2C的地址不一样就不会冲突
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 注册

本版积分规则 需要先绑定手机号

Archiver|联系我们|极客工坊

GMT+8, 2024-3-29 10:35 , Processed in 0.062820 second(s), 26 queries .

Powered by Discuz! X3.4 Licensed

Copyright © 2001-2021, Tencent Cloud.

快速回复 返回顶部 返回列表